mirror of
https://github.com/python/cpython.git
synced 2026-08-03 23:55:47 -04:00
Bernát GáborandGitHub
0d540afcec
A user function that shadows the `.`/`source` builtin hijacks the activate.fish prompt. fish resolves functions ahead of builtins, so the `echo "exit $status" | .` line that restores the exit status pipes into the user function instead of sourcing. Dot-style directory navigators redefine `.`, which made the prompt list the directory on every command and dropped the exit status handed to the original prompt. Route every builtin the prompt path uses (`source`, `echo`, `printf`, `set_color`, `functions`) through `builtin` so no user function can intercept them. These have all been fish builtins with a stable interface since fish 2.0.0, the version the script already required through `functions --copy`, so the minimum supported fish version does not change.
76 lines
2.5 KiB
Fish
76 lines
2.5 KiB
Fish
# This file must be used with "source <venv>/bin/activate.fish" *from fish*
|
|
# (https://fishshell.com/). You cannot run it directly.
|
|
|
|
function deactivate -d "Exit virtual environment and return to normal shell environment"
|
|
# reset old environment variables
|
|
if test -n "$_OLD_VIRTUAL_PATH"
|
|
set -gx PATH $_OLD_VIRTUAL_PATH
|
|
set -e _OLD_VIRTUAL_PATH
|
|
end
|
|
if test -n "$_OLD_VIRTUAL_PYTHONHOME"
|
|
set -gx PYTHONHOME $_OLD_VIRTUAL_PYTHONHOME
|
|
set -e _OLD_VIRTUAL_PYTHONHOME
|
|
end
|
|
|
|
if test -n "$_OLD_FISH_PROMPT_OVERRIDE"
|
|
set -e _OLD_FISH_PROMPT_OVERRIDE
|
|
# prevents error when using nested fish instances (Issue #93858)
|
|
if builtin functions -q _old_fish_prompt
|
|
builtin functions -e fish_prompt
|
|
builtin functions -c _old_fish_prompt fish_prompt
|
|
builtin functions -e _old_fish_prompt
|
|
end
|
|
end
|
|
|
|
set -e VIRTUAL_ENV
|
|
set -e VIRTUAL_ENV_PROMPT
|
|
if test "$argv[1]" != "nondestructive"
|
|
# Self-destruct!
|
|
builtin functions -e deactivate
|
|
end
|
|
end
|
|
|
|
# Unset irrelevant variables.
|
|
deactivate nondestructive
|
|
|
|
set -gx VIRTUAL_ENV __VENV_DIR__
|
|
if string match -qr 'CYGWIN|MSYS|MINGW' (uname)
|
|
set -gx VIRTUAL_ENV (cygpath -u $VIRTUAL_ENV)
|
|
end
|
|
|
|
set -gx _OLD_VIRTUAL_PATH $PATH
|
|
set -gx PATH "$VIRTUAL_ENV/"__VENV_BIN_NAME__ $PATH
|
|
set -gx VIRTUAL_ENV_PROMPT __VENV_PROMPT__
|
|
|
|
# Unset PYTHONHOME if set.
|
|
if set -q PYTHONHOME
|
|
set -gx _OLD_VIRTUAL_PYTHONHOME $PYTHONHOME
|
|
set -e PYTHONHOME
|
|
end
|
|
|
|
if test -z "$VIRTUAL_ENV_DISABLE_PROMPT"
|
|
# fish uses a function instead of an env var to generate the prompt.
|
|
|
|
# Save the current fish_prompt function as the function _old_fish_prompt.
|
|
builtin functions -c fish_prompt _old_fish_prompt
|
|
|
|
# With the original prompt function renamed, we can override with our own.
|
|
# Call every builtin through `builtin` so a user function that shadows
|
|
# `printf`, `set_color`, `echo`, or `source`/`.` cannot hijack the prompt
|
|
# (Issue #140006).
|
|
function fish_prompt
|
|
# Save the return status of the last command.
|
|
set -l old_status $status
|
|
|
|
# Output the venv prompt; color taken from the blue of the Python logo.
|
|
builtin printf "%s(%s)%s " (builtin set_color 4B8BBE) __VENV_PROMPT__ (builtin set_color normal)
|
|
|
|
# Restore the return status of the previous command.
|
|
builtin echo "exit $old_status" | builtin source -
|
|
# Output the original/"old" prompt.
|
|
_old_fish_prompt
|
|
end
|
|
|
|
set -gx _OLD_FISH_PROMPT_OVERRIDE "$VIRTUAL_ENV"
|
|
end
|