From 82ed9cc085eb72ff19993c613a739e56e1a1bdcb Mon Sep 17 00:00:00 2001
From: Bernard Cafarelli <voyageur@gentoo.org>
Date: Tue, 31 Mar 2026 21:54:09 +0200
Subject: [PATCH] x11-misc/picom: v13 bump

Update python compat range

Signed-off-by: Bernard Cafarelli <voyageur@gentoo.org>
---
 x11-misc/picom/Manifest          |  1 +
 x11-misc/picom/picom-13.ebuild   | 67 ++++++++++++++++++++++++++++++++
 x11-misc/picom/picom-9999.ebuild |  4 +-
 3 files changed, 70 insertions(+), 2 deletions(-)
 create mode 100644 x11-misc/picom/picom-13.ebuild

diff --git a/x11-misc/picom/Manifest b/x11-misc/picom/Manifest
index 93e394b46370..5d72fdb08815 100644
--- a/x11-misc/picom/Manifest
+++ b/x11-misc/picom/Manifest
@@ -1 +1,2 @@
 DIST picom-12.5.tar.gz 674165 BLAKE2B e74498032d474de70452272f4cffaad1d86de9a82e642f94322f523d1b3db206f4b7f0f4e9da60033f903a99c635489ec5ae87ef73daba2caf3c2e487d26d255 SHA512 e4e8d8d6edc5fd5115ee880ee36e3b217b07336e09c457a3eb9a4824c19ac4f98ae807c3a902f327e7a2d036e2ae2d1ab2a5da8bdee47e33e49faebf4893a78b
+DIST picom-13.tar.gz 656067 BLAKE2B bb3229bf2d8ad2bf93c5fc4a42478090800c1e742ad93771ff7f8a3664cf0c5a6d938e1cbf195488491f797b5ee5748e5d7c4030787b34d17b203bfea8d7ca1e SHA512 8b5a096b20f3dde86145917d38409a081f26f22a90be5b658308af1fcd06b068b2fb3db70efc45f2f42b32a38c82a28a8835838308addcebcfc5409a934dc22a
diff --git a/x11-misc/picom/picom-13.ebuild b/x11-misc/picom/picom-13.ebuild
new file mode 100644
index 000000000000..4efb848a282a
--- /dev/null
+++ b/x11-misc/picom/picom-13.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..14} )
+inherit meson python-any-r1 virtualx xdg
+
+DESCRIPTION="A lightweight compositor for X11 (previously a compton fork)"
+HOMEPAGE="https://github.com/yshui/picom"
+SRC_URI="https://github.com/yshui/picom/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MPL-2.0 MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="dbus +doc +drm opengl pcre test"
+
+REQUIRED_USE="test? ( dbus )" # avoid "DBus support not compiled in!"
+RESTRICT="test" # but tests require dbus_next
+
+RDEPEND="dev-libs/libconfig:=
+	dev-libs/libev
+	dev-libs/uthash
+	x11-libs/libX11
+	x11-libs/libxcb
+	x11-libs/pixman
+	x11-libs/xcb-util
+	x11-libs/xcb-util-image
+	x11-libs/xcb-util-renderutil
+	dbus? ( sys-apps/dbus )
+	drm? ( x11-libs/libdrm )
+	opengl? (
+		media-libs/libepoxy
+		virtual/opengl
+	)
+	pcre? ( dev-libs/libpcre2:= )"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto"
+BDEPEND="virtual/pkgconfig
+	doc? ( dev-ruby/asciidoctor )
+	test? ( $(python_gen_any_dep 'dev-python/xcffib[${PYTHON_USEDEP}]') )
+"
+
+DOCS=( README.md picom.sample.conf )
+
+python_check_deps() {
+	python_has_version "dev-python/xcffib[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use dbus)
+		$(meson_use doc with_docs)
+		$(meson_use opengl)
+		$(meson_use pcre regex)
+	)
+
+	meson_src_configure
+}
+
+src_test() {
+	virtx "${S}/tests/run_tests.sh" "${BUILD_DIR}/src/${PN}"
+}
diff --git a/x11-misc/picom/picom-9999.ebuild b/x11-misc/picom/picom-9999.ebuild
index d6b45b376e57..31344faa43fc 100644
--- a/x11-misc/picom/picom-9999.ebuild
+++ b/x11-misc/picom/picom-9999.ebuild
@@ -1,9 +1,9 @@
-# Copyright 1999-2024 Gentoo Authors
+# Copyright 1999-2026 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
 
-PYTHON_COMPAT=( python3_{9..13} )
+PYTHON_COMPAT=( python3_{9..14} )
 inherit git-r3 meson python-any-r1 virtualx xdg
 
 DESCRIPTION="A lightweight compositor for X11 (previously a compton fork)"