mirror of
https://anongit.gentoo.org/git/repo/gentoo.git
synced 2026-05-06 07:27:03 -04:00
Michał Górny
60 lines
1.4 KiB
Bash
60 lines
1.4 KiB
Bash
# Copyright 1999-2026 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
DISTUTILS_EXT=1
|
|
DISTUTILS_USE_PEP517=setuptools
|
|
PYTHON_COMPAT=( python3_{12..14} )
|
|
|
|
inherit distutils-r1
|
|
|
|
DESCRIPTION="Policy Analysis Tools for SELinux"
|
|
HOMEPAGE="https://github.com/SELinuxProject/setools/wiki"
|
|
|
|
if [[ ${PV} == *9999* ]] ; then
|
|
inherit git-r3
|
|
EGIT_REPO_URI="https://github.com/SELinuxProject/setools.git"
|
|
S="${WORKDIR}/${P}"
|
|
else
|
|
SRC_URI="https://github.com/SELinuxProject/setools/releases/download/${PV}/${P}.tar.bz2"
|
|
KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
|
|
S="${WORKDIR}/${PN}"
|
|
fi
|
|
|
|
LICENSE="GPL-2 LGPL-2.1"
|
|
SLOT="0"
|
|
IUSE="gui test"
|
|
RESTRICT="!test? ( test )"
|
|
|
|
RDEPEND="${PYTHON_DEPS}
|
|
>=dev-python/networkx-2.6[${PYTHON_USEDEP}]
|
|
dev-python/setuptools[${PYTHON_USEDEP}]
|
|
>=sys-libs/libsepol-3.2:=
|
|
>=sys-libs/libselinux-3.2:=
|
|
gui? (
|
|
dev-python/pyqt6[gui,widgets,${PYTHON_USEDEP}]
|
|
dev-python/pygraphviz[${PYTHON_USEDEP}]
|
|
)"
|
|
DEPEND="${RDEPEND}"
|
|
BDEPEND=">=dev-python/cython-0.29.14[${PYTHON_USEDEP}]
|
|
test? (
|
|
dev-python/pyqt6[gui,testlib,widgets,${PYTHON_USEDEP}]
|
|
dev-python/pytest-qt[${PYTHON_USEDEP}]
|
|
sys-apps/checkpolicy
|
|
)"
|
|
|
|
distutils_enable_tests pytest
|
|
|
|
python_prepare_all() {
|
|
sed -i "s@^lib_dirs = .*@lib_dirs = ['${ROOT:-/}usr/$(get_libdir)']@" "${S}"/setup.py || \
|
|
die "failed to set lib_dirs"
|
|
|
|
distutils-r1_python_prepare_all
|
|
}
|
|
|
|
python_test() {
|
|
rm -rf setools || die
|
|
epytest
|
|
}
|