mirror of
https://github.com/neovim/neovim.git
synced 2026-05-06 08:26:45 -04:00
Christian Clason
7ed6966023
runtime(ftplugin): Use "*" browsefilter pattern to match "All Files" Problem: The "*.*" browsefilter pattern only matches all files on Windows (Daryl Lee) Solution: Use "*" to filter on all platforms but keep "*.*" as the label text on Windows. (Fixes vim/vim#12685, Doug Kearns) The *.* browsefilter pattern used to match "All Files" on Windows is a legacy of the DOS 8.3 filename wildcard matching algorithm. For reasons of backward compatibility this still works on Windows to match all files, even those without an extension. However, this pattern only matches filenames containing a dot on other platforms. This often makes files without an extension difficult to access from the file dialog, e.g., "Makefile" On Windows it is still standard practice to use "*.*" for the filter label so ftplugins should use "All Files (*.*)" on Windows and "All Files (*)" on other platforms. This matches Vim's default browsefilter values. This commit also normalises the browsefilter conditional test to check for the Win32 and GTK GUI features and an unset b:browsefilter. closes: vim/vim#12759 https://github.com/vim/vim/commit/93197fde0f1db09b1e495cf3eb14a8f42c318b80 Co-authored-by: Doug Kearns <dougkearns@gmail.com>
64 lines
1.7 KiB
VimL
64 lines
1.7 KiB
VimL
" Vim filetype plugin
|
|
" Language: awk, nawk, gawk, mawk
|
|
" Maintainer: Doug Kearns <dougkearns@gmail.com>
|
|
" Previous Maintainer: Antonio Colombo <azc100@gmail.com>
|
|
" Last Change: 2024 Jan 14
|
|
|
|
" This plugin was prepared by Mark Sikora
|
|
" This plugin was updated as proposed by Doug Kearns
|
|
|
|
" Only do this when not done yet for this buffer
|
|
if exists("b:did_ftplugin")
|
|
finish
|
|
endif
|
|
|
|
" Don't load another plugin for this buffer
|
|
let b:did_ftplugin = 1
|
|
|
|
let s:cpo_save = &cpo
|
|
set cpo&vim
|
|
|
|
setlocal comments=:#
|
|
setlocal commentstring=#\ %s
|
|
setlocal formatoptions-=t formatoptions+=croql
|
|
|
|
setlocal define=function
|
|
setlocal suffixesadd+=.awk
|
|
|
|
let b:undo_ftplugin = "setl fo< com< cms< def< sua<"
|
|
|
|
" TODO: set this in scripts.vim?
|
|
if exists("g:awk_is_gawk")
|
|
setlocal include=@include
|
|
setlocal suffixesadd+=.gawk
|
|
if has("unix") || has("win32unix")
|
|
setlocal formatprg=gawk\ -f-\ -o/dev/stdout
|
|
let b:undo_ftplugin .= " | setl fp<"
|
|
endif
|
|
|
|
" Disabled by default for security reasons.
|
|
if dist#vim#IsSafeExecutable('awk', 'gawk')
|
|
let path = system("gawk 'BEGIN { printf ENVIRON[\"AWKPATH\"] }'")
|
|
let path = substitute(path, '^\.\=:\|:\.\=$\|:\.\=:', ',,', 'g') " POSIX cwd
|
|
let path = substitute(path, ':', ',', 'g')
|
|
|
|
let &l:path = path
|
|
endif
|
|
let b:undo_ftplugin .= " | setl inc< path<"
|
|
endif
|
|
|
|
if (has("gui_win32") || has("gui_gtk")) && !exists("b:browsefilter")
|
|
let b:browsefilter = "Awk Source Files (*.awk, *.gawk)\t*.awk;*.gawk\n"
|
|
if has("win32")
|
|
let b:browsefilter .= "All Files (*.*)\t*\n"
|
|
else
|
|
let b:browsefilter .= "All Files (*)\t*\n"
|
|
endif
|
|
let b:undo_ftplugin .= " | unlet! b:browsefilter"
|
|
endif
|
|
|
|
let &cpo = s:cpo_save
|
|
unlet s:cpo_save
|
|
|
|
" vim: nowrap sw=2 sts=2 ts=8
|