mirror of
https://anongit.gentoo.org/git/repo/gentoo.git
synced 2026-05-06 07:27:03 -04:00
media-libs/gst-plugins-base: drop 1.24.11-r1, 1.24.13
Bug: https://bugs.gentoo.org/970986 Signed-off-by: Alfred Wingate <parona@protonmail.com> Part-of: https://codeberg.org/gentoo/gentoo/pulls/802 Signed-off-by: Sam James <sam@gentoo.org>
This commit is contained in:
Alfred Wingate
committed by
Sam James
Sam James
parent
e602da5861
commit
14255d3a49
@@ -1,2 +1 @@
|
||||
DIST gst-plugins-base-1.24.11.tar.xz 2455952 BLAKE2B efbf7b1aaece5a287738afb93e4b99c27471c640079bc7312f84925309de0eb91ecb9837eab314e5f787d745fda6c9113105156bd819db64c869ddec6a04e7ff SHA512 b0a2a072c52628b85ae3d2ff8f2769f149fd2d0c3644fb9d9d934ea586835e29af97f41731023969a8120a470f998080ef5a0cac5aa26823d01698dfe2a5e2fb
|
||||
DIST gst-plugins-base-1.24.13.tar.xz 2468556 BLAKE2B 6b187799f58ada3d56143ade2392dbaff74dcd77afce382013e6c3a7adae0584f45f1313bc84453fab00f8e3989f70e5b3c31d372370f1bb4529da8805fe4642 SHA512 e770175c6ad9613f1b4f7d10a8106342d1b261663863d7414d0012c25856c5418fbbd65792478cb403141fd4bc79f1567bfd249ae27393eac3a05b9ad7888aca
|
||||
|
||||
@@ -1,150 +0,0 @@
|
||||
# Copyright 1999-2025 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
GST_ORG_MODULE="gst-plugins-base"
|
||||
|
||||
inherit flag-o-matic gstreamer-meson
|
||||
|
||||
DESCRIPTION="Basepack of plugins for gstreamer"
|
||||
HOMEPAGE="https://gstreamer.freedesktop.org/"
|
||||
|
||||
LICENSE="GPL-2+ LGPL-2+"
|
||||
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~sparc x86 ~x64-macos ~x64-solaris"
|
||||
|
||||
# For OpenGL we have three separate concepts, with a list of possibilities in each:
|
||||
# * opengl APIs - opengl and/or gles2; USE=opengl and USE=gles2 enable these accordingly; if neither is enabled, OpenGL helper library and elements are not built at all and all the other options aren't relevant
|
||||
# * opengl platforms - glx and/or egl; also cgl, wgl, eagl for non-linux; USE="X opengl" enables glx platform; USE="egl" enables egl platform. Rest is up for relevant prefix teams.
|
||||
# * opengl windowing system - x11, wayland, win32, cocoa, android, viv_fb, gbm and/or dispmanx; USE=X enables x11 (but for WSI it's automagic - FIXME), USE=wayland enables wayland, USE=gbm enables gbm (automagic upstream - FIXME); rest is up for relevant prefix/arch teams/contributors to test and provide patches
|
||||
# With the following limitations:
|
||||
# * If opengl and/or gles2 is enabled, a platform has to be enabled - x11 or egl in our case, but x11 (glx) is acceptable only with opengl
|
||||
# * If opengl and/or gles2 is enabled, a windowing system has to be enabled - x11, wayland or gbm in our case
|
||||
# * glx platform requires opengl API (but we don't REQUIRED_USE that as USE=X is common, glx is just disabled with USE=-opengl or USE=-X)
|
||||
# * wayland, gbm and most other non-glx WSIs require egl platform
|
||||
# Additionally there is optional dmabuf support with egl for additional dmabuf based upload/download/eglimage options;
|
||||
# and optional graphene usage for gltransformation and glvideoflip elements and more GLSL Uniforms support in glshader;
|
||||
# and libpng/jpeg are required for gloverlay element;
|
||||
|
||||
# Keep default IUSE options for relevant ones mirrored with gst-plugins-gtk and gst-plugins-bad
|
||||
IUSE="alsa +egl gbm +gles2 +introspection ivorbis +ogg opengl +orc +pango theora +vorbis wayland +X"
|
||||
GL_REQUIRED_USE="
|
||||
|| ( gbm wayland X )
|
||||
wayland? ( egl )
|
||||
gbm? ( egl )
|
||||
"
|
||||
REQUIRED_USE="
|
||||
ivorbis? ( ogg )
|
||||
theora? ( ogg )
|
||||
vorbis? ( ogg )
|
||||
opengl? ( || ( egl X ) ${GL_REQUIRED_USE} )
|
||||
gles2? ( egl ${GL_REQUIRED_USE} )
|
||||
"
|
||||
|
||||
# Dependencies needed by opengl library and plugin (enabled via USE gles2 and/or opengl)
|
||||
# dmabuf automagic from libdrm headers (drm_fourcc.h) and EGL, so ensure it with USE=egl (platform independent header used only, thus no MULTILIB_USEDEP); provides dmabuf based upload/download/eglimage options
|
||||
GL_DEPS="
|
||||
|| (
|
||||
>=media-libs/mesa-24.1.0_rc1[opengl,wayland?,${MULTILIB_USEDEP}]
|
||||
<media-libs/mesa-24.1.0_rc1[egl(+)?,gbm(+)?,gles2?,wayland?,${MULTILIB_USEDEP}]
|
||||
)
|
||||
egl? (
|
||||
x11-libs/libdrm
|
||||
)
|
||||
gbm? (
|
||||
>=dev-libs/libgudev-147[${MULTILIB_USEDEP}]
|
||||
>=x11-libs/libdrm-2.4.55[${MULTILIB_USEDEP}]
|
||||
)
|
||||
wayland? (
|
||||
>=dev-libs/wayland-1.20.0[${MULTILIB_USEDEP}]
|
||||
>=dev-libs/wayland-protocols-1.15
|
||||
)
|
||||
|
||||
>=media-libs/graphene-1.4.0[${MULTILIB_USEDEP}]
|
||||
media-libs/libpng:0[${MULTILIB_USEDEP}]
|
||||
media-libs/libjpeg-turbo:0=[${MULTILIB_USEDEP}]
|
||||
" # graphene for optional gltransformation and glvideoflip elements and more GLSL Uniforms support in glshader; libpng/jpeg for gloverlay element
|
||||
# >=media-libs/graphene-1.4.0[${MULTILIB_USEDEP}]
|
||||
|
||||
RDEPEND="
|
||||
app-text/iso-codes
|
||||
>=virtual/zlib-1.2.8-r1:=[${MULTILIB_USEDEP}]
|
||||
alsa? ( >=media-libs/alsa-lib-1.0.27.2[${MULTILIB_USEDEP}] )
|
||||
introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2:= )
|
||||
ivorbis? ( >=media-libs/tremor-0_pre20130223[${MULTILIB_USEDEP}] )
|
||||
ogg? ( >=media-libs/libogg-1.3.0[${MULTILIB_USEDEP}] )
|
||||
orc? ( >=dev-lang/orc-0.4.33[${MULTILIB_USEDEP}] )
|
||||
kernel_linux? ( >=x11-libs/libdrm-2.4.55[${MULTILIB_USEDEP}] )
|
||||
pango? ( >=x11-libs/pango-1.36.3[${MULTILIB_USEDEP}] )
|
||||
theora? ( >=media-libs/libtheora-1.1.1:=[encode,${MULTILIB_USEDEP}] )
|
||||
vorbis? ( >=media-libs/libvorbis-1.3.3-r1[${MULTILIB_USEDEP}] )
|
||||
X? (
|
||||
>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
|
||||
>=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
|
||||
>=x11-libs/libXv-1.0.10[${MULTILIB_USEDEP}]
|
||||
)
|
||||
|
||||
gles2? ( ${GL_DEPS} )
|
||||
opengl? ( ${GL_DEPS} )
|
||||
"
|
||||
DEPEND="${RDEPEND}
|
||||
dev-util/glib-utils
|
||||
X? ( x11-base/xorg-proto )
|
||||
"
|
||||
|
||||
DOCS=( AUTHORS NEWS README.md RELEASE )
|
||||
|
||||
PATCHES=(
|
||||
)
|
||||
|
||||
multilib_src_configure() {
|
||||
filter-flags -mno-sse -mno-sse2 -mno-sse4.1 #610340
|
||||
|
||||
# opus: split to media-plugins/gst-plugins-opus
|
||||
GST_PLUGINS_NOAUTO="alsa gl ogg pango theora vorbis x11 xshm xvideo"
|
||||
|
||||
local emesonargs=(
|
||||
-Dtools=enabled
|
||||
|
||||
$(meson_feature alsa)
|
||||
$(meson_feature kernel_linux drm)
|
||||
$(meson_feature ogg)
|
||||
$(meson_feature pango)
|
||||
$(meson_feature theora)
|
||||
$(meson_feature vorbis)
|
||||
$(meson_feature X x11)
|
||||
$(meson_feature X xshm)
|
||||
$(meson_feature X xvideo)
|
||||
)
|
||||
|
||||
if use opengl || use gles2; then
|
||||
# because meson doesn't like extraneous commas
|
||||
local gl_api=( $(use opengl && echo opengl) $(use gles2 && echo gles2) )
|
||||
local gl_platform=( $(use X && use opengl && echo glx) $(use egl && echo egl) )
|
||||
local gl_winsys=(
|
||||
$(use X && echo x11)
|
||||
$(use wayland && echo wayland)
|
||||
$(use egl && echo egl)
|
||||
$(use gbm && echo gbm)
|
||||
)
|
||||
|
||||
emesonargs+=(
|
||||
-Dgl=enabled
|
||||
-Dgl-graphene=enabled
|
||||
-Dgl_api=$(IFS=, ; echo "${gl_api[*]}")
|
||||
-Dgl_platform=$(IFS=, ; echo "${gl_platform[*]}")
|
||||
-Dgl_winsys=$(IFS=, ; echo "${gl_winsys[*]}")
|
||||
)
|
||||
else
|
||||
emesonargs+=(
|
||||
-Dgl=disabled
|
||||
-Dgl_api=
|
||||
-Dgl_platform=
|
||||
-Dgl_winsys=
|
||||
)
|
||||
fi
|
||||
|
||||
# Workaround EGL/eglplatform.h being built with X11 present
|
||||
use X || export CFLAGS="${CFLAGS} -DEGL_NO_X11"
|
||||
|
||||
gstreamer_multilib_src_configure
|
||||
}
|
||||
@@ -1,188 +0,0 @@
|
||||
# Copyright 1999-2026 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
GST_ORG_MODULE="gst-plugins-base"
|
||||
|
||||
inherit flag-o-matic meson-multilib gstreamer-meson virtualx
|
||||
|
||||
DESCRIPTION="Basepack of plugins for gstreamer"
|
||||
HOMEPAGE="https://gstreamer.freedesktop.org/"
|
||||
|
||||
LICENSE="GPL-2+ LGPL-2+"
|
||||
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~sparc x86 ~x64-macos ~x64-solaris"
|
||||
|
||||
# For OpenGL we have three separate concepts, with a list of possibilities in each:
|
||||
# * opengl APIs - opengl and/or gles2; USE=opengl and USE=gles2 enable these accordingly; if neither is enabled, OpenGL helper library and elements are not built at all and all the other options aren't relevant
|
||||
# * opengl platforms - glx and/or egl; also cgl, wgl, eagl for non-linux; USE="X opengl" enables glx platform; USE="egl" enables egl platform. Rest is up for relevant prefix teams.
|
||||
# * opengl windowing system - x11, wayland, win32, cocoa, android, viv_fb, gbm and/or dispmanx; USE=X enables x11 (but for WSI it's automagic - FIXME), USE=wayland enables wayland, USE=gbm enables gbm (automagic upstream - FIXME); rest is up for relevant prefix/arch teams/contributors to test and provide patches
|
||||
# With the following limitations:
|
||||
# * If opengl and/or gles2 is enabled, a platform has to be enabled - x11 or egl in our case, but x11 (glx) is acceptable only with opengl
|
||||
# * If opengl and/or gles2 is enabled, a windowing system has to be enabled - x11, wayland or gbm in our case
|
||||
# * glx platform requires opengl API (but we don't REQUIRED_USE that as USE=X is common, glx is just disabled with USE=-opengl or USE=-X)
|
||||
# * wayland, gbm and most other non-glx WSIs require egl platform
|
||||
# Additionally there is optional dmabuf support with egl for additional dmabuf based upload/download/eglimage options;
|
||||
# and optional graphene usage for gltransformation and glvideoflip elements and more GLSL Uniforms support in glshader;
|
||||
# and libpng/jpeg are required for gloverlay element;
|
||||
|
||||
# Keep default IUSE options for relevant ones mirrored with gst-plugins-gtk and gst-plugins-bad
|
||||
IUSE="alsa +egl gbm +gles2 +introspection ivorbis +ogg opengl +orc +pango theora +vorbis wayland +X"
|
||||
GL_REQUIRED_USE="
|
||||
|| ( gbm wayland X )
|
||||
wayland? ( egl )
|
||||
gbm? ( egl )
|
||||
"
|
||||
REQUIRED_USE="
|
||||
ivorbis? ( ogg )
|
||||
theora? ( ogg )
|
||||
vorbis? ( ogg )
|
||||
opengl? ( || ( egl X ) ${GL_REQUIRED_USE} )
|
||||
gles2? ( egl ${GL_REQUIRED_USE} )
|
||||
"
|
||||
|
||||
# Dependencies needed by opengl library and plugin (enabled via USE gles2 and/or opengl)
|
||||
# dmabuf automagic from libdrm headers (drm_fourcc.h) and EGL, so ensure it with USE=egl (platform independent header used only, thus no MULTILIB_USEDEP); provides dmabuf based upload/download/eglimage options
|
||||
GL_DEPS="
|
||||
>=media-libs/mesa-24.1.0_rc1[opengl,wayland?,${MULTILIB_USEDEP}]
|
||||
egl? (
|
||||
x11-libs/libdrm
|
||||
)
|
||||
gbm? (
|
||||
>=dev-libs/libgudev-147[${MULTILIB_USEDEP}]
|
||||
>=x11-libs/libdrm-2.4.55[${MULTILIB_USEDEP}]
|
||||
)
|
||||
wayland? (
|
||||
>=dev-libs/wayland-1.20.0[${MULTILIB_USEDEP}]
|
||||
>=dev-libs/wayland-protocols-1.15
|
||||
)
|
||||
|
||||
>=media-libs/graphene-1.4.0[${MULTILIB_USEDEP}]
|
||||
media-libs/libpng:0=[${MULTILIB_USEDEP}]
|
||||
media-libs/libjpeg-turbo:0=[${MULTILIB_USEDEP}]
|
||||
" # graphene for optional gltransformation and glvideoflip elements and more GLSL Uniforms support in glshader; libpng/jpeg for gloverlay element
|
||||
# >=media-libs/graphene-1.4.0[${MULTILIB_USEDEP}]
|
||||
|
||||
RDEPEND="
|
||||
app-text/iso-codes
|
||||
>=virtual/zlib-1.2.8-r1:=[${MULTILIB_USEDEP}]
|
||||
alsa? ( >=media-libs/alsa-lib-1.0.27.2[${MULTILIB_USEDEP}] )
|
||||
introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2:= )
|
||||
ivorbis? ( >=media-libs/tremor-0_pre20130223[${MULTILIB_USEDEP}] )
|
||||
ogg? ( >=media-libs/libogg-1.3.0[${MULTILIB_USEDEP}] )
|
||||
orc? ( >=dev-lang/orc-0.4.33[${MULTILIB_USEDEP}] )
|
||||
kernel_linux? ( >=x11-libs/libdrm-2.4.55[${MULTILIB_USEDEP}] )
|
||||
pango? ( >=x11-libs/pango-1.36.3[${MULTILIB_USEDEP}] )
|
||||
theora? ( >=media-libs/libtheora-1.1.1:=[encode,${MULTILIB_USEDEP}] )
|
||||
vorbis? ( >=media-libs/libvorbis-1.3.3-r1[${MULTILIB_USEDEP}] )
|
||||
X? (
|
||||
>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
|
||||
>=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
|
||||
>=x11-libs/libXv-1.0.10[${MULTILIB_USEDEP}]
|
||||
)
|
||||
|
||||
gles2? ( ${GL_DEPS} )
|
||||
opengl? ( ${GL_DEPS} )
|
||||
"
|
||||
DEPEND="${RDEPEND}
|
||||
dev-util/glib-utils
|
||||
X? ( x11-base/xorg-proto )
|
||||
"
|
||||
|
||||
DOCS=( AUTHORS NEWS README.md RELEASE )
|
||||
|
||||
multilib_src_configure() {
|
||||
filter-flags -mno-sse -mno-sse2 -mno-sse4.1 #610340
|
||||
|
||||
# opus: split to media-plugins/gst-plugins-opus
|
||||
GST_PLUGINS_NOAUTO="alsa gl ogg pango theora vorbis x11 xshm xvideo"
|
||||
|
||||
local emesonargs=(
|
||||
$(meson_native_enabled tools)
|
||||
|
||||
$(meson_feature alsa)
|
||||
$(meson_feature kernel_linux drm)
|
||||
$(meson_feature ogg)
|
||||
$(meson_feature pango)
|
||||
$(meson_feature theora)
|
||||
$(meson_feature vorbis)
|
||||
$(meson_feature X x11)
|
||||
$(meson_feature X xshm)
|
||||
$(meson_feature X xvideo)
|
||||
)
|
||||
|
||||
if use opengl || use gles2; then
|
||||
# because meson doesn't like extraneous commas
|
||||
local gl_api=( $(use opengl && echo opengl) $(use gles2 && echo gles2) )
|
||||
local gl_platform=( $(use X && use opengl && echo glx) $(use egl && echo egl) )
|
||||
local gl_winsys=(
|
||||
$(use X && echo x11)
|
||||
$(use wayland && echo wayland)
|
||||
$(use egl && echo egl)
|
||||
$(use gbm && echo gbm)
|
||||
)
|
||||
|
||||
emesonargs+=(
|
||||
-Dgl=enabled
|
||||
-Dgl-graphene=enabled
|
||||
-Dgl_api=$(IFS=, ; echo "${gl_api[*]}")
|
||||
-Dgl_platform=$(IFS=, ; echo "${gl_platform[*]}")
|
||||
-Dgl_winsys=$(IFS=, ; echo "${gl_winsys[*]}")
|
||||
)
|
||||
else
|
||||
emesonargs+=(
|
||||
-Dgl=disabled
|
||||
-Dgl_api=
|
||||
-Dgl_platform=
|
||||
-Dgl_winsys=
|
||||
)
|
||||
fi
|
||||
|
||||
# Workaround EGL/eglplatform.h being built with X11 present
|
||||
use X || export CFLAGS="${CFLAGS} -DEGL_NO_X11"
|
||||
|
||||
gstreamer_multilib_src_configure
|
||||
}
|
||||
|
||||
multilib_src_test() {
|
||||
# User env may cause issues (notably dconf isnt multilib)
|
||||
export GSETTINGS_BACKEND=memory
|
||||
|
||||
# Homebrew test skips for meson
|
||||
local -a tests
|
||||
tests=( $(meson test --list -C "${BUILD_DIR}") )
|
||||
|
||||
local -a _skip_tests=(
|
||||
# flaky
|
||||
pipelines_gl_launch_lines
|
||||
)
|
||||
|
||||
# Affects abi_x86_32
|
||||
multilib_is_native_abi || _skip_tests+=(
|
||||
# failed ABI check
|
||||
libs_libsabi
|
||||
# ../glib-2.84.4/gobject/gtype.c:4159: type id '284' is invalid
|
||||
libs_dsd
|
||||
# general:test_max_s8:0: Assertion 'memcmp (res, out, 4) == 0' failed
|
||||
elements_volume
|
||||
)
|
||||
|
||||
# Add suites which in this case are PN
|
||||
if has_version ">=dev-build/meson-1.10.0"; then
|
||||
local -a skip_tests=()
|
||||
for skip_test in ${_skip_tests[@]}; do
|
||||
skip_tests+=( "${PN}:${skip_test}" )
|
||||
done
|
||||
else
|
||||
local -a skip_tests=( ${_skip_tests[@]} )
|
||||
fi
|
||||
unset _skip_tests
|
||||
|
||||
for test_index in ${!tests[@]}; do
|
||||
if [[ ${skip_tests[@]} =~ ${tests[${test_index}]} ]]; then
|
||||
unset tests[${test_index}]
|
||||
fi
|
||||
done
|
||||
|
||||
# gstreamer_multilib_src_test doesn't pass arguments
|
||||
GST_GL_WINDOW=x11 virtx meson_src_test --timeout-multiplier 5 ${tests[@]}
|
||||
}
|
||||
Reference in New Issue
Block a user