x11-themes/tela-icon-theme: add 20250210

Signed-off-by: Mattéo Rossillol‑‑Laruelle <beatussum@protonmail.com>
Part-of: https://github.com/gentoo/gentoo/pull/42464
Closes: https://github.com/gentoo/gentoo/pull/42464
Signed-off-by: Sam James <sam@gentoo.org>

x11-themes/tela-icon-theme/Manifest

@@ -1 +1,2 @@
 DIST tela-icon-theme-20240419.tar.gz 3495225 BLAKE2B c9c97e183b8f35576dc68a4d1243d944d8528420e4759080052fbfccc1246bd18d0c29b9665ce55764ebb3e7fddb1fb1c92a015a03f6f764183938b26b780088 SHA512 f3d714c73b0624970c5758fee9785f363650e0c064771713d9499aa219880918e6d48cb5ffb457179a8baedd5e9d799f427f0c08dab746ab9932f4d95fda794d
+DIST tela-icon-theme-20250210.tar.gz 3547040 BLAKE2B 3f3e9cee563a8c12c31a660be2efcef724f3e39f792eb3f8655cb1cbbf3c02c4bc3b4af040cb680f808fd53c6d640a2283dc4342d36e46a6963bb9a79291cbbe SHA512 34ea8a448839082232c9cc1edc207bf2f91b822be76d5727149df150a85aed0760eb608a68ed5e9cf6623bc34d571d257331958ca16e7ac449d41fd241d3d8d4

x11-themes/tela-icon-theme/tela-icon-theme-20250210.ebuild

@@ -0,0 +1,91 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit check-reqs edo xdg
+
+MY_PN="${PN^}"
+MY_PV="${PV:0:4}-${PV:4:2}-${PV:6:2}" # eg. 20211225 -> 2021-12-25
+
+DESCRIPTION="A flat colorful Design icon theme"
+HOMEPAGE="https://github.com/vinceliuice/Tela-icon-theme"
+
+if [[ "${PV}" == 99999999 ]]; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/vinceliuice/Tela-icon-theme.git"
+else
+	SRC_URI="https://github.com/vinceliuice/Tela-icon-theme/archive/refs/tags/${MY_PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~ppc64"
+	S="${WORKDIR}/${MY_PN}-${MY_PV}"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="+hardlink kde minimal"
+RESTRICT="binchecks strip test"
+
+BDEPEND="
+	app-shells/bash
+	hardlink? ( sys-apps/util-linux[hardlink] )
+"
+
+DOCS=(
+	AUTHORS
+	README.md
+	tela-dark.png
+	tela-light.png
+)
+
+tela-icon-theme_check-reqs() {
+	if ! use minimal; then
+		if use hardlink; then
+			CHECKREQS_DISK_USR=1700M
+		else
+			CHECKREQS_DISK_USR=2600M
+		fi
+
+		check-reqs_${EBUILD_PHASE_FUNC}
+	fi
+}
+
+pkg_setup() {
+	tela-icon-theme_check-reqs
+}
+
+pkg_pretend() {
+	tela-icon-theme_check-reqs
+}
+
+src_prepare() {
+	default
+
+	# We use eclass for that.
+	sed -i "/gtk-update-icon-cache/d" install.sh || die
+}
+
+src_install() {
+	einstalldocs
+
+	dodir /usr/share/icons
+
+	local options=()
+
+	use kde && options+=( -c )
+
+	if use minimal; then
+		options+=( standard )
+	else
+		options+=( -a )
+	fi
+
+	edob ./install.sh -d "${ED}/usr/share/icons" "${options[@]}"
+
+	use hardlink && \
+		edob -m "Linking duplicate icons" hardlink -pot "${ED}/usr/share/icons"
+
+	# Installs broken symlinks (by design, but we remove it due to QA warnings).
+	# https://bugs.gentoo.org/830467
+	edob -m "Removing broken symlinks" find "${ED}" -xtype l -print -delete
+}

x11-themes/tela-icon-theme/tela-icon-theme-99999999.ebuild

@@ -1,4 +1,4 @@
-# Copyright 1999-2024 Gentoo Authors
+# Copyright 1999-2025 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -17,7 +17,7 @@ if [[ "${PV}" == 99999999 ]]; then
 	EGIT_REPO_URI="https://github.com/vinceliuice/Tela-icon-theme.git"
 else
 	SRC_URI="https://github.com/vinceliuice/Tela-icon-theme/archive/refs/tags/${MY_PV}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="amd64 arm64 ppc64"
+	KEYWORDS="~amd64 ~arm64 ~ppc64"
 	S="${WORKDIR}/${MY_PN}-${MY_PV}"
 fi