dev-ada/gnatcoll-core: add 26.0.0

Signed-off-by: Alfredo Tupone <tupone@gentoo.org>

dev-ada/gnatcoll-core/Manifest

@@ -1 +1,2 @@
 DIST gnatcoll-core-25.0.0.tar.gz 7492612 BLAKE2B 6c9653b74d575b24a5433dc56214f9fd55d8dfce65921d2f3172521d3f2c542e34e09df99c224634bf87da6068cffd4f47fdf6ed68f2b913d355a9f6ebff1624 SHA512 efa19b9760bd16b402445d4932dfd28f087f9a09b91ec688c6976b7b83fe5986580b1871378ac024e9a712df8ee75963e5dc88629a72ee1ce76f1d1403b8e122
+DIST gnatcoll-core-26.0.0.tar.gz 7526941 BLAKE2B 82068d0a0e875f5fb00c141a3ec10a08e2dd8bd717e576066d8d8c3303845e7e3d4f02f4fde9585497e931f9f4dc5dd90872dd12e1a42d0a15dcc6d6c5a3e1c5 SHA512 59a3ac4c911f1d2950964afc9ad5508a9cbd1facb0d1a49caaab8dea18376e287cbbe1948c2ae6a21de3e8488aa0b4d4a94d53f55529a909123e2db0c6c38cde

dev-ada/gnatcoll-core/gnatcoll-core-26.0.0.ebuild

@@ -0,0 +1,134 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+ADA_COMPAT=( gcc_{13..16} )
+PYTHON_COMPAT=( python3_{10..13} )
+inherit ada python-any-r1 multiprocessing
+
+DESCRIPTION="GNAT Component Collection Core packages"
+HOMEPAGE="https://github.com/AdaCore/gnatcoll-core/"
+SRC_URI="https://github.com/AdaCore/${PN}/archive/refs/tags/v${PV}.tar.gz
+	-> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc minimal +projects +shared static-libs static-pic test"
+RESTRICT="test"
+REQUIRED_USE="|| ( shared static-libs static-pic )
+	${ADA_REQUIRED_USE}
+	projects? ( !minimal )"
+
+RDEPEND="
+	projects? (
+		~dev-ada/libgpr-${PV}:=[${ADA_USEDEP},static-libs?,static-pic?]
+	)
+"
+BDEPEND="${RDEPEND}
+	dev-ada/gprbuild[${ADA_USEDEP}]
+	$(python_gen_any_dep '
+		test? ( dev-ada/e3-testsuite[${PYTHON_USEDEP}] )
+		doc? (
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]
+		)
+	')"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-25.0.0-gentoo.patch
+)
+
+python_check_deps() {
+	if use doc && use test ; then
+		python_has_version "dev-python/sphinx[${PYTHON_USEDEP}]" &&
+		python_has_version "dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]" &&
+		python_has_version "dev-ada/e3-testsuite[${PYTHON_USEDEP}]" || return 1
+
+		return 0
+	elif use test; then
+		python_has_version "dev-ada/e3-testsuite[${PYTHON_USEDEP}]" || return 1
+
+		return 0
+	elif use doc; then
+		python_has_version "dev-python/sphinx[${PYTHON_USEDEP}]" &&
+		python_has_version "dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]" || return 1
+	fi
+
+	return 0
+}
+
+pkg_setup() {
+	if use doc || use test; then
+		python-any-r1_pkg_setup
+	fi
+	ada_pkg_setup
+}
+
+src_prepare() {
+	default
+	sed -i \
+		-e "s:@GNATLS@:${GNATLS}:g" \
+		projects/src/gnatcoll-projects.ads \
+		|| die
+}
+
+src_compile() {
+	export GPR_PROJECT_PATH=minimal:core
+	build() {
+		gprbuild -v -p -m -P$2/gnatcoll_$2.gpr -j$(makeopts_jobs) \
+			-XGNATCOLL_VERSION=$(ver_cut 1-2) -XLIBRARY_TYPE=$1 \
+			-cargs:C ${CFLAGS} -cargs:Ada ${ADAFLAGS} || die
+	}
+	buildAll () {
+		build $1 minimal
+		use minimal && return
+		build $1 core
+		use projects && build $1 projects
+	}
+	if use shared; then
+		buildAll relocatable
+	fi
+	if use static-libs; then
+		buildAll static
+	fi
+	if use static-pic; then
+		buildAll static-pic
+	fi
+	use doc && emake -C docs html
+}
+
+src_test() {
+	#To be run after installation
+	cd testsuite
+	./run-tests || die
+}
+
+src_install() {
+	export GPR_PROJECT_PATH=minimal:core
+	build() {
+		gprinstall -v -P$2/gnatcoll_$2.gpr -XGNATCOLL_VERSION=$(ver_cut 1-2) \
+			-p -f --prefix="${D}"/usr --sources-subdir=include/gnatcoll_$2 \
+			-XLIBRARY_TYPE=$1 --build-name=$1 --build-var=LIBRARY_TYPE || die
+	}
+	buildAll () {
+		build $1 minimal
+		use minimal && return
+		build $1 core
+		use projects && build $1 projects
+	}
+	if use shared; then
+		buildAll relocatable
+	fi
+	if use static-libs; then
+		buildAll static
+	fi
+	if use static-pic; then
+		buildAll static-pic
+	fi
+	insinto /usr/share/gpr
+	doins gnatcoll.gpr
+	use doc && HTML_DOCS=( docs/_build/html/* )
+	einstalldocs
+	rm -r "${D}"/usr/share/gpr/manifests
+}