net-mail/automx2: add 2026.0

Closes: https://bugs.gentoo.org/969995
Signed-off-by: Ralph Seichter <github@seichter.de>
Part-of: https://github.com/gentoo/gentoo/pull/45805
Closes: https://github.com/gentoo/gentoo/pull/45805
Signed-off-by: Sam James <sam@gentoo.org>

net-mail/automx2/Manifest

@@ -1 +1,2 @@
 DIST automx2-2025.1.tar.gz 175571 BLAKE2B c3c7bbeb6f438a24a476ca6d14b4529ea51869786b3d53f8ef1202a4955259274674683614e0ddadc456d1f7d3e1b9ca20b18d266e4ff8aa54c683456834f92f SHA512 cbaaee4863e7bb265a4c2b991395b8ef3b6405be28beded53287328fb766d1ddb12fde0fdf4ea8992ed0b8abba0e83a018b60054e778a97c734a9a68c391d776
+DIST automx2-2026.0.tar.gz 175808 BLAKE2B bfab6658191faf5924fa7dc75914f921cf468d102c63b16afe4ee8cd15daa558718280d5a8e9bd5fd5dd69ab44474179ec45c31afe44d3a560f235543ec75866 SHA512 0196919ca208b605692b461c4537afb19c7e68ae35573c2b5f04da4af8b7c9dc313d2777a4cf049e6bfe5bc00d495633b1edfea5cf91cf25e46d6b73558da441

net-mail/automx2/automx2-2026.0.ebuild

@@ -0,0 +1,46 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=(python3_{11..13})
+
+inherit distutils-r1
+
+DESCRIPTION="Mail User Agent (email client) configuration made easy"
+HOMEPAGE="https://rseichter.github.io/automx2/"
+SRC_URI="https://github.com/rseichter/automx2/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND="acct-user/automx2
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/flask-migrate[${PYTHON_USEDEP}]
+	dev-python/flask-sqlalchemy[${PYTHON_USEDEP}]
+	dev-python/ldap3[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests unittest
+
+python_prepare_all() {
+	rm -r src/alembic || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local -x AUTOMX2_CONF="tests/unittest.conf"
+	eunittest tests/
+}
+
+python_install_all() {
+	local DOCS=("${S}"/docs/*.pdf)
+	local HTML_DOCS=("${S}"/docs/*.{html,svg})
+	newconfd "${FILESDIR}/confd" "${PN}"
+	newinitd "${FILESDIR}/init-r2" "${PN}"
+	insinto /etc
+	newins "${FILESDIR}/conf" "${PN}.conf"
+	distutils-r1_python_install_all
+}