dev-libs/kdsingleapplication: add 1.2.1

Signed-off-by: Bernard Cafarelli <voyageur@gentoo.org>

dev-libs/kdsingleapplication/Manifest

@@ -1 +1,2 @@
 DIST kdsingleapplication-1.2.0.tar.gz 87265 BLAKE2B 64d3ba9f17551fb1547218419deaea2234fe1233a5a626449ff632f9b17235392bb34f6b296bca2fe3ef2b113ee0e412f328362cde8cfbea1769ae7d15af922a SHA512 2832f53b70258af1bfe9d66d67ab1c46be720ccab632d1b76353a171414cea00a03c576ad34eeefb2648330a311867f7fde7efb96b1f16159dc206f890bc1085
+DIST kdsingleapplication-1.2.1.tar.gz 87731 BLAKE2B 9ecd8299b71443984f05bf228410a9b10c86bf68cc88681fb65bce74a32032b4f26c6f02be5af01373bda08426e612c818a8e044af78e2efbe4c547b661e6176 SHA512 7c8aa168a3183805f6fc5a4e5675527f9c14de0b7c0924333c8cc29b092000d35ed46044c4b8f4b2e68ee59e64fcb4ae04df83f4899ffa5128f8871eb3929a25

dev-libs/kdsingleapplication/kdsingleapplication-1.2.1.ebuild

@@ -0,0 +1,56 @@
+# Copyright 2024-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake qmake-utils
+
+DESCRIPTION="KDAB's helper class for single-instance policy applications"
+HOMEPAGE="https://github.com/KDAB/KDSingleApplication"
+SRC_URI="https://github.com/KDAB/KDSingleApplication/releases/download/v${PV}/kdsingleapplication-${PV}.tar.gz"
+S="${WORKDIR}"/KDSingleApplication-${PV}
+
+LICENSE="BSD MIT"
+SLOT="0/$(ver_cut 1-2)" # ${PROJECT_NAME}_SOVERSION
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+
+IUSE="doc examples test"
+RESTRICT="!test? ( test )"
+
+DEPEND="dev-qt/qtbase:6[network,widgets]"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	doc? (
+		app-text/doxygen[dot]
+		dev-qt/qttools:6[assistant]
+	)
+	examples? ( dev-util/patchelf )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DINSTALL_DOC_DIR="${EPREFIX}/usr/share/doc/${PF}"
+		-DKDSingleApplication_QT6=ON
+		-DKDSingleApplication_DOCS=$(usex doc)
+		-DKDSingleApplication_EXAMPLES=$(usex examples)
+		-DKDSingleApplication_TESTS=$(usex test)
+	)
+	use doc && mycmakeargs+=(
+		-DQHELPGEN_EXECUTABLE="$(qt6_get_libexecdir)/qhelpgenerator"
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	if use doc; then
+		if use examples; then
+			rm -r "${BUILD_DIR}"/docs/api/html/examples || die
+		fi
+		local HTML_DOCS=( "${BUILD_DIR}"/docs/api/html/. )
+	fi
+	if use examples; then
+		patchelf --remove-rpath "${BUILD_DIR}"/bin/widgetsingleapplication || die
+		dobin "${BUILD_DIR}"/bin/widgetsingleapplication
+	fi
+	cmake_src_install
+}