net-vpn/cloudflare-warp: new package, add 2025.10.186.0

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

net-vpn/cloudflare-warp/Manifest

@@ -0,0 +1 @@
+DIST cloudflare-warp-2025.10.186.0.x86_64.rpm 54862462 BLAKE2B 5cfada712257102d5ce2877a76a5dc84d8849a4597cf9a3e970b3719c06825d9c8e697cb2933a5c523ea8e4e66e790b7109dc7d44f69b3ed9b85ccbeedc83136 SHA512 e223a89dac1a6ad1c6dbef235fdab281785e285c563204527837dbcd89f0090e4e1158c1e80c20b4d4b32d760b8cac42432c20ccd6e5219e4f86be820073b58f

net-vpn/cloudflare-warp/cloudflare-warp-2025.10.186.0.ebuild

@@ -0,0 +1,58 @@
+# Copyright 2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit rpm systemd xdg desktop
+
+DESCRIPTION="Cloudflare Warp Client"
+HOMEPAGE="https://1.1.1.1"
+SRC_URI="
+	https://downloads.cloudflareclient.com/v1/download/fedora35-intel/version/${PV}
+		-> ${P}.x86_64.rpm
+"
+S="${WORKDIR}"
+
+LICENSE="all-rights-reserved"
+SLOT="0"
+KEYWORDS="-* ~amd64"
+IUSE="+gui"
+RESTRICT="bindist mirror"
+
+DEPEND="
+	dev-libs/glib
+	dev-libs/nspr
+	dev-libs/nss
+	net-firewall/nftables
+	net-libs/libpcap
+	sys-apps/dbus
+	x11-libs/cairo
+	gui? (
+		x11-libs/gdk-pixbuf:2
+		x11-libs/gtk+:3
+		x11-libs/pango
+	)
+"
+RDEPEND="${DEPEND}"
+
+src_unpack() {
+	rpm_unpack ${A}
+}
+
+src_install() {
+	dobin bin/warp-{cli,dex,diag,svc}
+	systemd_dounit opt/cloudflare-warp/warp-svc.service
+
+	if use gui; then
+		dobin bin/{warp-desktop-svc,warp-taskbar}
+		systemd_douserunit usr/lib/systemd/user/warp-desktop-svc.service
+		domenu usr/share/applications/com.cloudflare.WarpTaskbar.desktop
+
+		doicon -s scalable usr/share/icons/hicolor/scalable/apps/*.svg
+		insinto /usr/share/warp/images
+		doins usr/share/warp/images/*.png
+
+		insinto /etc/xdg/autostart
+		doins etc/xdg/autostart/com.cloudflare.WarpTaskbar.desktop
+	fi
+}

net-vpn/cloudflare-warp/metadata.xml

@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>arthurzam@gentoo.org</email>
+		<name>Arthur Zamarin</name>
+	</maintainer>
+</pkgmetadata>