kde-apps/kio-extras: 26.04.0 version bump

Signed-off-by: Sam James <sam@gentoo.org>
2026-05-06 07:27:03 -04:00 · 2026-04-16 17:30:48 +01:00
parent f870c144f9
commit a55aa1cb7e
2 changed files with 107 additions and 0 deletions
@@ -1 +1,2 @@
 DIST kio-extras-25.12.3.tar.xz 5595468 BLAKE2B 6a6780d91fd79dcfb415aa0a4bb5254134ed12cd04a158568b7b18f94b1dfd45fa4c888650c1f6117997d98121ceda3d6b75579ed8d7e8f966f11818fab12d38 SHA512 a1eea90a6826fe882cca31b69672f1bb4a3c00c3002ee1b459a407debbf420b3882bb097c85d75f7ac727eaefba04b60739751fdbf9b03a13e8b2a67dc6a7691
+DIST kio-extras-26.04.0.tar.xz 5598804 BLAKE2B 490d758c4654c106d09062edece5ea1d8be78e5cc9f7e4d4c948d53c292d7fde1f605b5a5bf2b6dabe6c30c9240883082f5c0dfa7c984ed11bd56915e45c09e3 SHA512 002f788539bab2a419bdfad574b24193aef5f231092911e81addfb4816d30e86eb13ca3fba1de6204c336176c54a2dc516a678fbb2e8fbaedf57dcb9f8ef0d07
@@ -0,0 +1,106 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+ECM_TEST="true"
+KFMIN=6.22.0
+QTMIN=6.10.1
+inherit ecm gear.kde.org optfeature xdg
+
+DESCRIPTION="KIO plugins present a filesystem-like view of arbitrary data"
+HOMEPAGE="https://invent.kde.org/network/kio-extras"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="6"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="activities ios +man mtp nfs +libproxy openexr samba +sftp taglib X"
+
+# requires running Plasma environment
+RESTRICT="test"
+
+DEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,widgets,xml]
+	>=dev-qt/qtsvg-${QTMIN}:6
+	kde-apps/libkexiv2:6
+	>=kde-frameworks/karchive-${KFMIN}:6
+	>=kde-frameworks/kcmutils-${KFMIN}:6
+	>=kde-frameworks/kcodecs-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kdbusaddons-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/kparts-${KFMIN}:6
+	>=kde-frameworks/kservice-${KFMIN}:6
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	>=kde-frameworks/solid-${KFMIN}:6
+	>=kde-frameworks/syntax-highlighting-${KFMIN}:6
+	activities? (
+		>=dev-qt/qtbase-${QTMIN}:6[sql]
+		kde-plasma/plasma-activities:6=
+		kde-plasma/plasma-activities-stats:6
+	)
+	ios? (
+		app-pda/libimobiledevice:=
+		app-pda/libplist:=
+	)
+	libproxy? (
+		>=kde-frameworks/knotifications-${KFMIN}:6
+		net-libs/libproxy
+	)
+	mtp? ( >=media-libs/libmtp-1.1.16:= )
+	nfs? ( net-libs/libtirpc:= )
+	openexr? ( media-libs/openexr:= )
+	samba? (
+		>=kde-frameworks/kdnssd-${KFMIN}:6
+		net-fs/samba[client]
+		>=net-libs/kdsoap-2.2.0:=[qt6(+)]
+		>=net-libs/kdsoap-ws-discovery-client-0.3.0
+	)
+	sftp? (
+		dev-libs/qcoro
+		>=net-libs/libssh-0.9.8:=[sftp]
+	)
+	taglib? ( >=media-libs/taglib-1.11.1:= )
+	X? (
+		x11-libs/libX11
+		x11-libs/libXcursor
+	)
+"
+RDEPEND="${DEPEND}
+	!kde-apps/kio-extras:5[-kf6compat(-)]
+	!kde-apps/kio-extras-kf5:5
+	!<kde-frameworks/kio-5.116.0-r2:5
+	!kde-frameworks/kio-trash-desktop-file:5
+	>=kde-frameworks/kded-${KFMIN}:6
+"
+BDEPEND="man? ( dev-util/gperf )"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_ACTIVITIES=$(usex activities)
+		$(cmake_use_find_package ios IMobileDevice)
+		$(cmake_use_find_package ios PList)
+		-DWITH_LIBPROXY=$(usex libproxy)
+		$(cmake_use_find_package man Gperf)
+		$(cmake_use_find_package mtp Libmtp)
+		$(cmake_use_find_package nfs TIRPC)
+		$(cmake_use_find_package openexr OpenEXR)
+		$(cmake_use_find_package samba Samba)
+		$(cmake_use_find_package sftp libssh)
+		$(cmake_use_find_package taglib Taglib)
+		-DWITHOUT_X11=$(usex !X)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	optfeature "alternative filename search backend" sys-apps/ripgrep
+	use samba && xdg_pkg_postinst
+}
+
+pkg_postrm() {
+	use samba && xdg_pkg_postrm
+}