sci-libs/indilib: add 2.2.1.1

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

sci-libs/indilib/Manifest

@@ -1,2 +1,3 @@
 DIST indilib-2.1.9.tar.gz 3331587 BLAKE2B 33ec27fa5a530f79f02f9b776d36c24d7a0646c45620a338692c7f9168a74287f83aa7a1f862f558cc4e1f43916deb1280d0ad38a677c051d7a07d3a4d15f8b5 SHA512 c3ed7bc362f032f07f619c6c56eb3a5f1fc00f76a31b800ecdd9d3a6a5eaa3fe01f7a216e5613d251224a52c6f7bf3e0684920b7020626bc030b2c74d1d03626
 DIST indilib-2.2.0.tar.gz 3397549 BLAKE2B ef883b5f27cf6fc2a6052ff21d160dc40a6de7e989be8e94963a8500ce741f219f279be45c15ba1d381297c4303edd3d48740a39ec1fc603ceede6f9a065ac1e SHA512 757fb016c954261c55b7d2d8492172107763ffb3d25647aed184b12922014e0c3ad3c0de5345ce6b7f7015e2f6be8e348d6b68f4db11eecd0601a9655a3b0432
+DIST indilib-2.2.1.1.tar.gz 3420281 BLAKE2B b72b85cbb5b5f750e338d05501a91ce4afa47eedb21413a4f14899b2bcbc70222614149dbe22a6248c1bdf729ac8d31339dcc04c5c24f7c5c3b6ee25a0a97b53 SHA512 c6a8043a3d757f027bdc80a3fc11366b06eee6e311d0cf4fdcd9a1d5e1b5b0a81e4248451bdc98cee1989248ce749477f4414fb09868fe2e88eaeb4a56a24eff

sci-libs/indilib/indilib-2.2.1.1.ebuild

@@ -0,0 +1,87 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake dot-a udev
+
+DESCRIPTION="INDI Astronomical Control Protocol library"
+HOMEPAGE="https://www.indilib.org/"
+SRC_URI="https://github.com/${PN}/${PN/lib/}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${P/lib/}"
+
+LICENSE="BSD GPL-2+ LGPL-2+ LGPL-2.1+"
+SLOT="0/1"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~riscv ~x86"
+IUSE="ogg rtlsdr test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-cpp/cpp-httplib:=
+	dev-cpp/nlohmann_json
+	dev-libs/hidapi
+	dev-libs/libev
+	media-libs/libjpeg-turbo:=
+	net-misc/curl
+	sci-libs/cfitsio:=
+	sci-libs/fftw:3.0=
+	sci-libs/gsl:=
+	sci-libs/libnova:=
+	virtual/zlib:=
+	virtual/libusb:1
+	ogg? (
+		media-libs/libogg
+		media-libs/libtheora:=
+	)
+	rtlsdr? ( net-wireless/rtl-sdr:= )
+"
+DEPEND="${RDEPEND}
+	kernel_linux? ( sys-kernel/linux-headers )
+	test? ( >=dev-cpp/gtest-1.8.0 )
+"
+
+src_configure() {
+	lto-guarantee-fat
+
+	local mycmakeargs=(
+		-DINDI_SYSTEM_HIDAPILIB=ON
+		-DINDI_SYSTEM_HTTPLIB=ON
+		-DINDI_SYSTEM_JSONLIB=ON
+		-DINDI_BUILD_QT_CLIENT=OFF
+		-DINDI_BUILD_SHARED=ON
+		-DINDI_BUILD_STATIC=OFF
+		-DINDI_BUILD_XISF=OFF # not packaged
+		-DUDEVRULES_INSTALL_DIR="${EPREFIX}$(get_udevdir)"/rules.d
+		-DINDI_BUILD_EXAMPLES=OFF # nothing is installed
+		$(cmake_use_find_package ogg OggTheora)
+		$(cmake_use_find_package rtlsdr RTLSDR)
+		-DINDI_BUILD_UNITTESTS=$(usex test)
+		-DINDI_BUILD_INTEGTESTS=$(usex test)
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	# Unit tests
+	BUILD_DIR="${BUILD_DIR}"/test cmake_src_test
+
+	# Integration tests
+	# They fail in parallel because they try to bind to the same port more
+	# than once.
+	BUILD_DIR="${BUILD_DIR}"/integs cmake_src_test -j1
+}
+
+src_install() {
+	cmake_src_install
+	strip-lto-bytecode
+}
+
+pkg_postinst() {
+	udev_reload
+}
+
+pkg_postrm() {
+	udev_reload
+}