app-crypt/uacme: new package, add 1.8.1

Signed-off-by: Patrick McLean <chutzpah@gentoo.org>

app-crypt/uacme/Manifest

@@ -0,0 +1 @@
+DIST uacme-1.8.1.tar.gz 252881 BLAKE2B 4ecf3cea1055b71cf7e995fa38127e95c2f7c35317b7026b071f487747c8208fc8d632858b49be9b041d8950f51f218cfd3796996de25a0faec3c4d7375e271d SHA512 96c6f9f54b412d8aa6f339ffc6616e7b1ce372cf1d796ade088adbd18d0d0a9e046363925315458a5ba1ccce8bbf5795453b5185869ed80aed668338c8adbf7d

app-crypt/uacme/metadata.xml

@@ -0,0 +1,15 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>chutzpah@gentoo.org</email>
+		<name>Patrick McLean</name>
+	</maintainer>
+	<use>
+		<flag name="openssl">Use <pkg>dev-libs/openssl</pkg> as TLS backend</flag>
+		<flag name="ualpn">Build uapln - lightweight proxying ACMEv2 tls-alpn-01 responder</flag>
+	</use>
+	<upstream>
+		<remote-id type="github">ndilieto/uacme</remote-id>
+	</upstream>
+</pkgmetadata>

app-crypt/uacme/uacme-1.8.1.ebuild

@@ -0,0 +1,63 @@
+# Copyright 2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit autotools
+
+DESCRIPTION="uacme is a client for the RFC8555 ACMEv2 protocol."
+HOMEPAGE="
+	https://github.com/ndilieto/uacme
+	https://ndilieto.github.io/uacme/uacme.html
+	https://ndilieto.github.io/uacme/ualpn.html
+"
+
+SRC_URI="
+	https://github.com/ndilieto/uacme/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz
+"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="doc gnutls +openssl +ualpn"
+
+DEPEND="
+	net-misc/curl:=
+	openssl? ( dev-libs/openssl:= )
+	gnutls? ( net-libs/gnutls:= )
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	doc? ( app-text/asciidoc )
+"
+
+REQUIRED_USE="
+	^^ ( gnutls openssl )
+"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local -a myeconfargs=(
+		--with-libcurl
+		$(use_enable doc docs)
+		$(use_with gnutls)
+		$(use_with openssl)
+		$(use_with ualpn)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	if ! use doc; then
+		doman uacme.1
+		use ualpn && doman ualpn.1
+	fi
+}