games-emulation/jgrf: add 1.4.0

Closes: https://github.com/gentoo/gentoo/pull/46120
Signed-off-by: orbea <orbea@riseup.net>
Signed-off-by: Michael Orlitzky <mjo@gentoo.org>

games-emulation/jgrf/Manifest

@@ -1,2 +1,3 @@
 DIST jgrf-1.2.2.tar.bz2 309537 BLAKE2B 4a915549b93d047e3035721d3a3b2a2f2f88d9efbc70cbda5200bbf337517d939d8b18b76f8259b0c3587a882044c797f6f77e6aaf5fd4c8415c044117b04f9d SHA512 e9660916904b0d5fdae3a2db6a9c18af9315efaf0b23a27ed149eb45299bf75c307bc711b8659e079c5f37e02a84ad92ef13fc889911b0d733700554e59bfd97
 DIST jgrf-1.3.0.tar.bz2 308766 BLAKE2B eea1fa63da02913e5f838dbd77a0830b4770f9f846459c2904245cab281af14b0e2095a3c8ec503ca4f6f26182ae2567ce20435dd1e4ae158403369a86028482 SHA512 47f18cfac8f9e9bdab2f92bfac7170f5fb8f51995acd1f2b7603781fed5f893a6467a009c06f400d085359b56d8b83e256308be542a62ebf0cd9e495b6334e08
+DIST jgrf-1.4.0.tar.bz2 325205 BLAKE2B 33b5a39c5538fcfe16b07c70e452741c78d4c32dfa64b7effcd7420511e152db15e0f81db314254201cbd46a510d863ab9a00b5fb1dfdf1ccab69512a432787d SHA512 7bd51affea19b7ce085997e3d7af49b584a694edb712d21b8a6cb85b24146911cc5de694fc7e81834cad39fd8c21584c1c694b24a3a0b14c4b5139b89df10ebf

games-emulation/jgrf/jgrf-1.4.0.ebuild

@@ -0,0 +1,51 @@
+# Copyright 2022-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs xdg
+
+DESCRIPTION="The Jolly Good Reference Frontend"
+HOMEPAGE="https://jgemu.gitlab.io/jgrf.html"
+if [[ "${PV}" == *9999 ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.com/jgemu/${PN}.git"
+else
+	SRC_URI="https://gitlab.com/jgemu/${PN}/-/archive/${PV}/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+fi
+
+LICENSE="BSD CC0-1.0 MIT ZLIB"
+SLOT="1"
+
+DEPEND="
+	dev-libs/miniz
+	dev-libs/openssl:0=
+	media-libs/jg:1=
+	media-libs/libepoxy[egl(+)]
+	media-libs/libsdl3[opengl]
+	media-libs/speexdsp
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+src_compile() {
+	emake \
+		CC="$(tc-getCC)" \
+		PKG_CONFIG="$(tc-getPKG_CONFIG)" \
+		PREFIX="${EPREFIX}"/usr \
+		LIBDIR="${EPREFIX}/usr/$(get_libdir)" \
+		USE_EXTERNAL_MD5=1 \
+		USE_EXTERNAL_MINIZ=1
+}
+
+src_install() {
+	emake install \
+		DESTDIR="${D}" \
+		PREFIX="${EPREFIX}"/usr \
+		DOCDIR="${EPREFIX}"/usr/share/doc/${PF} \
+		USE_EXTERNAL_MD5=1 \
+		USE_EXTERNAL_MINIZ=1
+}