llvm-core/libclc: Remove redundant targets

Replace the three amdgpu and nvidia targets with a single one,
as discussed on https://github.com/llvm/llvm-project/pull/194149.

Signed-off-by: Michał Górny <mgorny@gentoo.org>

llvm-core/libclc/libclc-22.1.4-r1.ebuild

@@ -0,0 +1,61 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LLVM_COMPAT=( 22 )
+PYTHON_COMPAT=( python3_{11..14} )
+inherit cmake llvm.org llvm-r1 python-any-r1
+
+DESCRIPTION="OpenCL C library"
+HOMEPAGE="https://libclc.llvm.org/"
+
+LICENSE="Apache-2.0-with-LLVM-exceptions || ( MIT BSD )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~riscv ~x86"
+IUSE="+spirv video_cards_nvidia video_cards_r600 video_cards_radeonsi"
+
+BDEPEND="
+	${PYTHON_DEPS}
+	$(llvm_gen_dep '
+		llvm-core/clang:${LLVM_SLOT}
+	')
+	spirv? (
+		>=dev-util/spirv-llvm-translator-22:*
+	)
+"
+
+LLVM_COMPONENTS=( libclc )
+llvm.org_set_globals
+
+pkg_setup() {
+	llvm-r1_pkg_setup
+	python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local libclc_targets=(
+		"clspv--"
+		"clspv64--"
+	)
+
+	use spirv && libclc_targets+=(
+		"spirv-mesa3d-"
+		"spirv64-mesa3d-"
+	)
+	use video_cards_nvidia && libclc_targets+=(
+		"nvptx64-nvidia-cuda"
+	)
+	use video_cards_r600 && libclc_targets+=(
+		"r600--"
+	)
+	use video_cards_radeonsi && libclc_targets+=(
+		"amdgcn-amd-amdhsa"
+	)
+
+	libclc_targets=${libclc_targets[*]}
+	local mycmakeargs=(
+		-DLIBCLC_TARGETS_TO_BUILD="${libclc_targets// /;}"
+	)
+	cmake_src_configure
+}

llvm-core/libclc/libclc-23.0.0.9999.ebuild

@@ -49,8 +49,6 @@ src_configure() {
 		"spirv64-mesa3d-"
 	)
 	use video_cards_nvidia && MULTIBUILD_VARIANTS+=(
-		"nvptx64--"
-		"nvptx64--nvidiacl"
 		"nvptx64-nvidia-cuda"
 	)
 	use video_cards_radeonsi && MULTIBUILD_VARIANTS+=(