sci-mathematics/vampire: bump to 5.0.1

Signed-off-by: Maciej Barć <xgqt@gentoo.org>

sci-mathematics/vampire/Manifest

@@ -1 +1,2 @@
 DIST vampire-5.0.0.tar.gz 2674000 BLAKE2B 2de6034223dd8f9be0634ed6b052a6feb5e337d63e3862e9dee2fa7c16afee9a6c94d48c0a5d4e7ddd1ef4111f9f4b4eb5d9a174fa76b56a54f884a4a422c50a SHA512 1cc6573d00d0eeee0f4d824a46f8dbb9702ba00245863b231da6d6a67655dfebb8815b336f29ea1455f71a9c0aec327d5d47babe0e960ccfb644ab0823e916e4
+DIST vampire-5.0.1.tar.gz 2649343 BLAKE2B fdc0a9390ce5a93cf2ff615b62ea7cab3400d706ca444a5f986b3d1d966369185f0226bccf13fe74d737b7bc1ef8dc894942b0280c6a76ac1964dff03d493958 SHA512 4809b1d6a81f4605a9374a21a9b9720fd4234cb803cbbcf7867a0afb338489dc61f0f12314c2f235cb00d789c2d807bda3f8549dd87e260a19217f6cd481b329

sci-mathematics/vampire/vampire-5.0.1.ebuild

@@ -0,0 +1,66 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CMAKE_IN_SOURCE_BUILD="true"
+
+inherit flag-o-matic cmake
+
+DESCRIPTION="The Vampire Prover, theorem prover for first-order logic"
+HOMEPAGE="https://vprover.github.io/
+	https://github.com/vprover/vampire/"
+
+if [[ ${PV} == *9999* ]] ; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/vprover/${PN}"
+else
+	SRC_URI="https://github.com/vprover/${PN}/releases/download/v${PV}/${PN}.tar.gz
+		-> ${P}.tar.gz"
+	S="${WORKDIR}/${PN}"
+
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="BSD"
+SLOT="0/${PV}"
+IUSE="test +z3"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	z3? (
+		dev-libs/gmp:=
+		>=sci-mathematics/z3-4.11.2:=
+	)
+"
+DEPEND="
+	${RDEPEND}
+"
+
+src_configure() {
+	# -Werror=strict-aliasing warnings, bug #863269
+	filter-lto
+	append-flags -fno-strict-aliasing
+
+	# Only compiles in the Debug build.
+	local CMAKE_BUILD_TYPE="Debug"
+
+	local -a mycmakeargs=(
+		-DZ3_DIR=$(usex z3 "/usr/$(get_libdir)/cmake/z3/" "")
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+
+	if use test ; then
+		eninja vtest
+	fi
+}
+
+src_install() {
+	dobin "${PN}"
+	einstalldocs
+}