app-forensics/afflib: add 3.7.22

Signed-off-by: Sam James <sam@gentoo.org>

app-forensics/afflib/Manifest

@@ -1 +1,2 @@
 DIST afflib-3.7.20.tar.gz 560441 BLAKE2B 6934efc30566b4b72e55e5727c46657362237872acae9d161f2625439d3d6e12da702b3ed82e3442b7015d8cb707097152cc73a6d0cc31d1ad61467f4022f7d4 SHA512 1ac623cb8462fc929a8ad1c014e92d319a3ebf5226ef07aa0777e4cbb77a9ee20adf570f39c960c9186ac2a477e861dfd5565d3364fdff22f9870f8c9ab30479
+DIST afflib-3.7.22.tar.gz 588290 BLAKE2B d3c63125a5a3823c0bc6ba8040ad596a1669713017ac92e57333d0b847ff19617c11ee4cc9d1ba5d8170a6c0629c89a2dada963d317a4247c39c15c3648712c2 SHA512 d649ce8198d8e6f05b6ba503fd9b454fceb06bf182dec8bc135eb126ad4b100301d7c4fc9ef6dac0f3d98edd785133bc841332333634f4534b8f51041ba51f43

app-forensics/afflib/afflib-3.7.22.ebuild

@@ -0,0 +1,80 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..13} )
+inherit autotools python-single-r1
+
+MY_PN=AFFLIBv3
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Library that implements the AFF image standard"
+HOMEPAGE="https://github.com/sshock/AFFLIBv3/"
+SRC_URI="https://github.com/sshock/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~x86 ~x64-macos"
+IUSE="fuse ncurses python qemu readline s3 static-libs threads"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+# Tests don't play well with sandbox
+RESTRICT="test"
+
+RDEPEND="
+	dev-libs/expat
+	virtual/zlib:=
+	fuse? ( sys-fs/fuse:3= )
+	dev-libs/openssl:=
+	ncurses? ( sys-libs/ncurses:= )
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep 'dev-python/cython[${PYTHON_USEDEP}]')
+	)
+	readline? ( sys-libs/readline:= )
+	s3? ( net-misc/curl )
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-3.7.19-search-path.patch"
+)
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e '/FLAGS/s: -g::' \
+		-e 's:-D_FORTIFY_SOURCE=2::' \
+		configure.ac || die
+
+	eautoreconf
+}
+
+src_configure() {
+	# Hacks for automagic dependencies
+	use ncurses || export ac_cv_lib_ncurses_initscr=no
+	use readline || export ac_cv_lib_readline_readline=no
+
+	local myeconfargs=(
+		$(use_enable fuse)
+		$(use_enable python)
+		$(use_enable qemu)
+		$(use_enable s3)
+		$(use_enable static-libs static)
+		$(use_enable threads threading)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	find "${ED}" -name "*.la" -delete || die
+}