mirror of
https://anongit.gentoo.org/git/repo/gentoo.git
synced 2026-05-06 07:27:03 -04:00
Jay Faulkner
84326d67aa
Adds upstream patch from https://review.opendev.org/c/openstack/python-openstackclient/+/984455 to enable tests passing on python 3.14. Signed-off-by: Jay Faulkner <jayf@gentoo.org>
64 lines
1.7 KiB
Bash
64 lines
1.7 KiB
Bash
# Copyright 1999-2026 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
DISTUTILS_USE_PEP517=pbr
|
|
PYTHON_COMPAT=( python3_{12..14} )
|
|
|
|
inherit distutils-r1 pypi
|
|
|
|
DESCRIPTION="A client for the OpenStack APIs"
|
|
HOMEPAGE="
|
|
https://opendev.org/openstack/python-openstackclient/
|
|
https://github.com/openstack/python-openstackclient/
|
|
https://pypi.org/project/python-openstackclient/
|
|
"
|
|
|
|
LICENSE="Apache-2.0"
|
|
SLOT="0"
|
|
KEYWORDS="amd64 arm64 ~riscv x86"
|
|
|
|
RDEPEND="
|
|
>=dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
|
|
>=dev-python/cliff-4.13.0[${PYTHON_USEDEP}]
|
|
>=dev-python/cryptography-2.7[${PYTHON_USEDEP}]
|
|
>=dev-python/openstacksdk-4.6.0[${PYTHON_USEDEP}]
|
|
>=dev-python/osc-lib-2.3.0[${PYTHON_USEDEP}]
|
|
>=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
|
|
>=dev-python/python-keystoneclient-3.22.0[${PYTHON_USEDEP}]
|
|
>=dev-python/python-cinderclient-3.3.0[${PYTHON_USEDEP}]
|
|
>=dev-python/requests-2.27.0[${PYTHON_USEDEP}]
|
|
>=dev-python/stevedore-2.0.1[${PYTHON_USEDEP}]
|
|
"
|
|
BDEPEND="
|
|
test? (
|
|
>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
|
|
>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
|
|
>=dev-python/requests-mock-1.2.0[${PYTHON_USEDEP}]
|
|
>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
|
|
>=dev-python/wrapt-1.7.0[${PYTHON_USEDEP}]
|
|
>=dev-python/ddt-1.0.1[${PYTHON_USEDEP}]
|
|
)
|
|
"
|
|
|
|
distutils_enable_tests unittest
|
|
|
|
PATCHES=(
|
|
# https://review.opendev.org/c/openstack/python-openstackclient/+/984455
|
|
"${FILESDIR}/0001-tests-Fix-test_module-for-Python-3.14.patch"
|
|
)
|
|
|
|
src_prepare() {
|
|
# Depends on a specific runner
|
|
sed -e 's/test_command_has_logger/_&/' \
|
|
-i openstackclient/tests/unit/common/test_command.py || die
|
|
|
|
distutils-r1_src_prepare
|
|
}
|
|
|
|
python_test() {
|
|
# functional tests require cloud instance access
|
|
eunittest -b openstackclient/tests/unit
|
|
}
|